Estrutura de Dados - Pilha Encadeada em Linguagem Pascal.

Aqui temos um exemplo de uma Pilha Encadeada escrita em Linguagem de Programação Pascal.
Inicio

Program Pilha;
uses crt;

Type dados=record
        produto:string;
        codigo:integer;
    End;        PilhaEnc=^NO;
        NO=record
            elemento:dados;
            ant:PilhaEnc;
        End;
    { Variável "P" aponta para o Topo da Pilha }
Procedure init (var P:PilhaEnc);
Begin
    P:=nil; 
End;

Function Vazia(P:PilhaEnc):boolean;
Begin
    if P=nil then
        Vazia:=true
    else Vazia:=false;    
End;    

Procedure Push(var P:PilhaEnc; _produto:string; _codigo:integer);
var P1:PilhaEnc;
Begin
    new(P1);
    P1^.elemento.produto:= _produto;
    P1^.elemento.codigo:= _codigo;
    if Vazia(P) then
    Begin
        P1^.ant:=nil;
        P:=P1;
    End    
    else
    Begin
            P1^.ant:=P;
            P:=P1;
    End;
End;

Procedure Mostrar(P:PilhaEnc);
Begin        
            Writeln; Writeln;
            Writeln('Codigo   : ',P^.elemento.codigo);                
            Writeln('Produto  : ',P^.elemento.produto);
     End;

Procedure Top (P: PilhaEnc);     
begin
    if not Vazia(P) then
        Mostrar(P)
    else    Writeln('            Pilha Vazia');
End;

Procedure Pop(var P:PilhaEnc);
var Pilha_aux:PilhaEnc;
Begin
    if not Vazia(P) then
    Begin        
        Pilha_aux:=P;      //Variavel Auxiliar para guardar o Topo da Pilha que é "P"
        Mostrar(Pilha_aux);
        P:=P^.ant;
        dispose(Pilha_aux);        
    End
    else Writeln('            Pilha Vazia');    
End;

Procedure Menu;
Begin
    Writeln;
    Writeln('-------------------');
    Writeln('--| 1 Push      |--');
    Writeln('--| 2 Top       |--');
    Writeln('--| 3 Pop       |--');
    Writeln('--| 0 Sair      |--');
    Writeln('-------------------');
End;

VAR
PE:PilhaEnc;
op:integer;

produto:string;    { Variaveis } //usadas apenas para inserir na Pilha.
codigo:integer;    { do Push   }


BEGIN
    init(PE);
    repeat
        Menu;
        Write('Opcao: ');
        readln(op);
        case op of
            1:     
                Begin
                    Writeln; Writeln;
                    Write('Informe Codigo: ');
                    readln(codigo);
                    Write('Nome do Produto: ');
                    readln(produto);
                    Push(PE,produto,codigo);
                End;
            2:
                Begin
                    Writeln;Writeln;
                    Writeln('        TOP');
                    Top(PE);
                End;
            3:
                Begin
                    Writeln;Writeln;
                    Writeln('        POP');
                    Pop(PE);
                End;
        End;
        readln;
        clrscr;        
    until(op=0);
END.

FIM!

Nessa Pilha foi criado um procedimento para mostrar o valor assim vai diminuindo a redundância de código. Para implementar pode ser feito da seguinte forma acrescentando variáveis:
Antes

Type dados=record
        produto:string;
        codigo:integer;
    End;

Depois

Type dados=record
        produto:string;
        codigo:integer;

        descricao:string;
        qtd:integer;

    End;

Terá que modificar no Procedimento Push e Mostrar:


Push ficaria assim:

Procedure Push(var P:PilhaEnc; _produto:string; _codigo:integer;_descricao:string; _qtd:integer);

var P1:PilhaEnc;
Begin
    new(P1);
    P1^.elemento.produto:= _produto;
    P1^.elemento.codigo:= _codigo;

    P1^.elemento.descricao:= _descricao;
    P1^.elemento.qtd:= _qtd;
    if Vazia(P) then
    Begin
        P1^.ant:=nil;
        P:=P1;
    End    
    else
    Begin
            P1^.ant:=P;
            P:=P1;
    End;
End;

Terá que mudar na passagem acrescentando duas novas variáveis e logo abaixo na atribuição.

Mostrar ficaria assim:

Procedure Mostrar(P:PilhaEnc);
Begin        
            Writeln; Writeln;
            Writeln('Codigo      : ',P^.elemento.codigo);                
            Writeln('Produto     : ',P^.elemento.produto);

            Writeln('Descricao   : ',P^.elemento.descricao);
            Writeln('Quantidade  : ',P^.elemento.qtd);

End;

Depois disso basta criar as variáveis globais qtd e descricao lá em variáveis do Push(onde tem o comentário), e pedir para informar, depois acrescentar na passagem do Procedimento Push. Ex.:

Push(PE,produto,codigo,descricao,qtd);

Pilha Encadeada em Pascal

Categories: Pascal , Programação